admin 管理员组

文章数量: 1184232

导读

我们需要监控某个服务进程是否启动，如果服务奔溃了就自动重启，这里以redis为例介绍一下如何在windows上写这种bat文件，来监控服务的状态

监控服务的运行状态

  • 脚本启动redis
    redis.bat文件的内容如下
@echo off
rem 隐藏redis启动后的cmd窗口
if "%1" == "h" goto begin
mshta vbscript:createobject("wscript.shell").run("%~nx0 h",0)(window.close)&&exit
:begin
rem 隐藏redis启动后的cmd窗口
title redis-server
C:
cd \software\Redis-x64-3.2.100
redis-server.exe redis.windows.conf 2>nul && echo ^>%date:~0,10% %time:~0,8% Reids启动程序成功
rem 程序执行完毕执行exit命令退出运行窗口
exit
  • 监控redis的服务状态
@echo off
rem 定义需监控程序的进程名和程序路径，可根据需要进行修改
set secs=60
set RedisName=redis-server.exe
title 监控redis服务的运行状态
cls
echo.
echo 进程监控开始……
echo.
rem 定义循环体
:startjc
   rem 监控redis服务
   tasklist /nh|findstr /i %RedisName% >nul
   rem 变量errorlevel的值等于0表示查找到进程，否则没有查找到进程
   if %errorlevel%==0 (
         echo ^>%date:~0,10% %time:~0,8% Redis服务正在运行……
    )else (
           echo ^>%date:~0,10% %time:~0,8% 正在重新启动Redis服务……
           start redis.bat 
   )   
   rem 用ping命令来实现延时运行
   ping -n %secs% 127.0.0.1 > nul
   goto startjc
echo on
pause

有时候我们需要开启多个服务进程，需要去检测服务启动的数量，如果服务数量变少了，我们就去新增几个，以达到某个数量，监控的脚本如下

   set WorkerNum=10
   set /a sum=%WorkerNum%-%number%
   if %sum%==0 (
		echo ^>%date:~0,10% %time:~0,8% Worker服务正在运行……
   )else (
	   for /l %%i in (1 1 %sum%) do (
		   echo ^>%date:~0,10% %time:~0,8% 正在重新启动NexWorker服务……
		   start worker.bat
	   )
   )

本文标签：

版权声明：本文标题：windows bat启动程序和监控程序自启动 内容由网友自发贡献，该文观点仅代表作者本人， 转载请联系作者并注明出处：http://www.roclinux.cn/b/1754824025a3040487.html， 本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌抄袭侵权/违法违规的内容，一经查实，本站将立刻删除。